User/Rdrg109/1/1

Add links
From Meta, a Wikimedia project coordination wiki

Introducción[edit]

Esta página contiene notas relacionadas a la reunión con WikiAcción Perú en la que participé el día 13 de julio del 2022.

Contenido[edit]

Conocimiento compartido durante la reunión[edit]

¿Cómo descubrí Wikidata?[edit]

Mi carrera es Ciencias de la computación. En el curso «Base de datos I», curso de 3er ciclo de la carrera Ciencias de la computación de la universidad UTEC, en la semana 13, tuvimos una clase sobre la web semántica, bases de datos orientada a grafos y los datos enlazados. En esa clase, nos dieron una breve introducción a SPARQL. El profesor Teofilo nos mostró una consulta de SPARQL que mostraba un mapa de todas las universidades del Perú, luego cambiando 3 caracteres en la consulta de SPARQL, pudo hacer lo mismo para universidades de Chile y China.

Esto me sorprendió mucho, pues antes la única manera que conocía para lograr antes de ese momento eso era hacerlo manualmente. Es decir, primero conseguir la lista de las universidades de esos países, luego buscar esas universidades en un mapa en línea (ejm. OpenStreetMap), guardar las coordenadas para cada una y luego buscar una manera de mostrar esos puntos en un mapa. Gracias a SPARQL, ahora puedo saber la ubicación de las universidades de cualquier país sin necesidad de hacer todos esos pasos.

¿Cómo me enteré del movimiento Wikimedia en Perú?[edit]

Al haber sido introducido a SPARQL y Wikidata, empecé a contribuir a Wikidata, y fui adentrandome más a los proyectos de Wikimedia. Durante este proceso, encontré el grupo de Telegram de Wikimedia Perú, me uní y comencé a contribuir a los esfuerzos de otros miembros en el grupo.

Posteriormente, participé en 2 talleres relacionados a Wikidata. El primero, fue una introducción a Wikidata (este evento fue documentado en esta página). El segundo, estuvo enfocado a la creación de libros en Wikidata (este evento no fue documentado).

Uso de SPARQL para consultar Wikidata[edit]

SPARQL es el lenguaje de programación con el que se puede consultar los datos de Wikidata para hacer minería de datos. Con este lenguaje se pueden responder preguntas básicas (ejm. ¿Qué escritores nacieron en Perú?), complejas (ejm. ¿Qué escritores nacieron y fallecieron en el mismo departamento de Perú?) y muy complejas (ejm. ¿Qué escritores nacieron en Perú y estudiaron en universidades ubicadas en otros países en un periodo donde esos países estaban en guerra?).

Hay muchas preguntas que se podrían responder en SPARQL en relación a los temas en los cuales WikiAcción Perú se enfoca. En la sección de abajo, Consultas de SPARQL en temáticas de WikiAcción Perú, he escrito algunas consultas enfocados en estos tres temas: ecología, cultura y género con el fin de mostrar todo lo que se puede hacer con Wikidata.

Por si quieren conocer más sobre SPARQL, en Wikidata, la comunidad también ha escrito un tutorial y está disponible en español. La comunidad también ha escrito esta página con ejemplos en varias areas del conocimiento. El anterior año, empecé a escribir esta página con ejemplos sólo enfocados a Perú y así sirva para mostrar el poder de SPARQL a otros peruanes interesados en Wikidata.

Consultas de SPARQL en temáticas de WikiAcción Perú[edit]

Esta sección contiene consultas de SPARQL enfocadas en 3 temáticas: ecología, cultura y género. Para ejecutar estas consultas y ver sus resultados, puede pegar el código en el servicio de consultas de Wikidata y presionar el botón azul mostrado en el lado izquierdo o presionar las teclas Control + Enter.

Ecología[edit]

Pregunta: ¿Cuál es el mapa de los zoológicos del Perú?

Gracias a los datos enlazados y semánticos que tiene Wikidata, esta consulta no solo listará los zoológicos, sino también aquellos lugares que también son considerados zoológicos, por ejemplo, mariposarios. De igual manera, podemos utilizar la consulta para mostrar sitios arqueológicos, universidades, museos, areas protegidas, etc. 

#defaultView:Map
SELECT
  ?item
  ?itemLabel
  ?clase
  ?claseLabel
  ?coordenadas
WITH {
  SELECT DISTINCT ?item {
    ?item wdt:P131* wd:Q419.
  }
} AS %0
WITH {
  SELECT DISTINCT ?item {
    INCLUDE %0.
    ?item wdt:P31/wdt:P279* wd:Q43501.
  }
} AS %1
WITH {
  SELECT ?item ?coordenadas {
    INCLUDE %1.
    ?item wdt:P625 ?coordenadas.
  }
} AS %2
{
  INCLUDE %2.
  ?item wdt:P31 ?clase.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}

Pregunta: ¿Qué árboles ubicados en Perú existen en Wikidata?

NOTA: Con «árboles», no me refiero a las especies, sino a un árbol como tal. Por ejemplo, en el Parque El Carmen, hay un árbol llamado Ombú y se dice que fue plantado por Don José De San Martín.

Escribí la consulta, pero devolvió 0 resultados. Escribí otra consulta para listar todos los árboles que existen en Wikidata en un mapa, y se puede ver que la mayoría se encuentra en Europa y Japón. Con esto, nos damos cuenta que la documentación de instancias de árboles es otro campo de datos de Perú que tiene por mejorar en Wikidata. 

SELECT ?item ?location {
  ?item wdt:P31 wd:Q10884;
        wdt:P625 ?location.
}

Pregunta: ¿Qué biólogos peruanes no tienen la propiedad "fecha de fallecimiento"?

La siguiente consulta lista aquellos biólogos peruanes que no tienen la propiedad "fecha de muerte". Esta consulta es útil porque obtiene aquellos que podrían seguir en vida, lo cual puede ser útil en caso se necesite contactar a un biólogo que podría tener conocimiento sobre la biología de Perú. 

SELECT
  ?fechaDeNacimiento
  ?peruane
  ?peruaneLabel
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}

    ?peruane wdt:P106 wd:Q864503.
  }
} AS %0
WITH {
  SELECT ?peruane {
    INCLUDE %0.
    FILTER NOT EXISTS {
      ?peruane wdt:P570|wdt:P20 [].
    }
  }
} AS %1
{
  INCLUDE %1.
  OPTIONAL{?peruane wdt:P569 ?fechaDeNacimiento}.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
ORDER BY DESC(?fechaDeNacimiento)
Cultura[edit]

Pregunta: ¿Qué peruanes tienen artículos en otras versiones de Wikipedia, pero no en Wikipedia en español?

La siguiente consulta lista aquellos peruanes que tienen página en Wikipedia en quechua, pero no en Wikipedia en español. La importancia de esta consulta es que nos permite encontrar peruanes que tal vez no son muy conocidos en un contexto donde se usa español, pues por esta razón el voluntario decidió crear el artículo en la otra lengua.

Esta misma consulta de SPARQL podría ser reutilizada con cualquier versión de Wikipedia para responder preguntar similares: ¿Qué peruanes tienen página en Wikipedia en aymara, pero no en Wikipedia en español? ¿Qué peruanes tienen página en Wikipedia en español, pero no en Wikipedia en inglés? 

SELECT ?peruane ?peruaneLabel ?qu
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT ?peruane ?qu {
    INCLUDE %0.
    OPTIONAL{
      ?qu schema:about ?peruane;
          schema:isPartOf <https://qu.wikipedia.org/>;
        }
    OPTIONAL{
      ?es schema:about ?peruane;
          schema:isPartOf <https://es.wikipedia.org/>;
        }
    FILTER(BOUND(?qu) && !BOUND(?es)).
  }
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]"}.
}


Pregunta: ¿Qué peruanes han sido matemáticos y recibido premios? 

#defaultView:Tree
SELECT
  ?peruane
  ?peruaneLabel
  ?premio
  ?premioLabel
WITH {
  SELECT DISTINCT ?peruane ?premio {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT DISTINCT ?peruane ?premio {
    INCLUDE %0.
    ?peruane
      wdt:P106/wdt:P279* wd:Q170790;
      wdt:P166 ?premio.
  }
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Género[edit]

Pregunta: ¿Qué mujeres en Wikidata no tienen la propiedad «ocupación»?

La siguiente consulta lista a aquellas mujeres peruanas que no tienen la propiedad "ocupación" en Wikidata. La importancia de esta consulta es que nos permite saber a que entidades le falta información y así poder esta información restante, para así hacer que peruanes sean descubiertos por otras personas del mundo (por ejemplo, un estudiante de Asia que estudia sobre la historia de la literatura de Lationamérica desearía encontrar a escritores peruanes). 

SELECT ?peruane ?peruaneLabel
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
    ?peruane wdt:P21 wd:Q6581072.
  }
} AS %0
WITH {
  SELECT ?peruane {
    INCLUDE %0.
    FILTER NOT EXISTS {
      ?peruane wdt:P106 [].
    }
  }
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]"}.
}

Pregunta: ¿Cuáles son las ocupaciones con más cantidad de peruanas en Wikidata? y ¿Cuántas hay para cada una de ellas?

Estas dos preguntas pueden ser respondidas con un diagrama de barras de ocupaciones que tienen las mujeres peruanas. La siguiente consulta de SPARQL hace eso.

La consulta ha sido limitada a mostrar 10 resultados, pues en total existen 352 ocupaciones que hacen mujeres peruanas, por lo que al mostrar todas, no se puede ver el nombre de las ocupaciones en el diagrama de barras. Esta consulta alternativa muestra la tabla con todas las ocupaciones y sus cantidades. 

#defaultView:BarChart
SELECT
  ?ocupación
  ?ocupaciónLabel
  ?conteo
WITH {
  SELECT DISTINCT ?peruana ?ocupación {
    {?peruana wdt:P27 wd:Q419 }
    UNION
    {?peruana wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruana wdt:P1532 wd:Q419}
    ?peruana wdt:P21 wd:Q6581072;
             wdt:P106 ?ocupación.
  }
} AS %0
WITH {
  SELECT ?ocupación (COUNT(*) AS ?conteo) {
    INCLUDE %0.
  }
  GROUP BY ?ocupación
  ORDER BY DESC(?conteo)
  LIMIT 10
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY DESC(?conteo)

Pregunta: ¿Qué son aquellas cosas cuyos autores son peruanas?

Sabemos que una persona puede ser autor de obras literarias, poemas, artículos académicos, artículos periodísticos, etc. Con la siguiente consulta podemos listar aquellas cosas que tienen como autores a mujeres peruanas, organizado por clase, y la mujer peruana que la realizó. 

SELECT
  ?clase
  ?claseLabel
  ?peruana
  ?peruanaLabel
  ?obra
  ?obraLabel
WITH {
  SELECT DISTINCT ?clase ?obra ?peruana {
    {?peruana wdt:P27 wd:Q419 }
    UNION
    {?peruana wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruana wdt:P1532 wd:Q419}

    ?peruana wdt:P21 wd:Q6581072.

    ?obra wdt:P50 ?peruana;
          wdt:P31 ?clase.
  }
} AS %0
WITH {
  SELECT ?clase (COUNT(*) AS ?conteo) {
    INCLUDE %0.
  }
  GROUP BY ?clase
} AS %1
{
  INCLUDE %0.
  INCLUDE %1.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
ORDER BY DESC(?conteo)

¿Cómo puedo contribuir a WikiAcción Perú?[edit]

  • Apoyo en la creación de contenido en una cuenta de Twitter relacionado a Wikidata y Peru
    • Durante la reunión, mencioné que no frecuento las redes sociales. Sin embargo, creo que Twitter es un buen medio poder llegar a otros peruanos y sepan lo que es posible hacer con Wikidata. Por esta razón, podría ayudar en escribir contenido en relación a Wikidata y otra persona podría encargarse de hacer las publicaciones y administrar la cuenta. Esta idea esta basada en una cuenta en Twitter llamada WikidataFacts que hace lo mismo, pero no esta enfocada en un tema en específico.
  • Participación en talleres relacionados a Wikidata
    • En los dos talleres, que mencioné anteriormente que realicé, me di cuenta que organizar un taller requiere preparación de diapositivas, material adicional y la realización de una metodología que permita que los asistentes entiendan nuevo conocimiento. Esto requiere tiempo y mi disponibilidad de tiempo a veces es reducida debido a que aún no termino mis estudios universitarios. Puedo organizar un taller si es que es planificado con suficiente anticipación. Sin embargo, creo que un caso ideal es que hayan varios peruanos wikimedistas que puedan organizar estos talleres de Wikidata. El siguiente punto tiene que ver con esto.
  • Capacitar a otros wikimedistas en Wikidata
    • Estoy dispuesto a compartir conocimiento relacionado a Wikidata (consultas de SPARQL, exploración de datos, herramientas que se pueden usar en Wikidata, OpenRefine, etc.) a otros wikimedistas peruanos. Esto con el objetivo que otros wikimedistas se sientan más familiarizados y puedan compartir este conocimiento o que sus contribuciones sean más significativas. Una manera como pensé hacer esto sería mediante reuniones virtuales o presenciales, en donde podríamos enfocarnos en un tema de Wikidata, o intentar solucionar las dificultades o preguntas que tengan sobre Wikidata. A diferencia de un taller, esto sería con un grupo más reducido y no sería sistemático como un taller.

Toolforge y demás herramientas útiles para los proyectos de Wikimedia[edit]

Toolforge es una plataforma que contiene herramientas creadas por wikimedistas para ayudar a otros wikimedistas a contribuir en los proyectos de Wikimedia. En esta categoría, se pueden encontrar algunas de esas herramientas.

Algunas herramientas que me parecen interesantes son

  • InteGraality
    • Crea tablas con información sobre propiedades que faltan añadir a elementos de Wikidata. Por ejemplo, en esta página, la herramienta fue utilizada para mostrar los porcentajes de propiedades faltantes en pinturas agrupadas por colección. Gracias a estas tablas, se puede ver que propiedades es la que falta añadir a pinturas en menor y mayor magnitud.
  • Twitter to Commons
    • Herramienta para subir imágenes de Twitter a Wikimedia Commons.

La siguiente lista contiene herramientas que no forman parte de Toolforge, pero también son administradas por la fundación Wikimedia, pueden ser utilizadas libremente y siento que también son de utilidad para los wikimedistas.

  • PetScan
    • Búsqueda avanzado en cualquier proyecto de Wikimedia.
  • Pageviews Analysis
    • Análisis de cantidad de visitas por página en cualquier proyecto de Wikimedia.
  • XTools
    • Estadísticas sobre las contribuciones de un usuario en cualquier proyectos de Wikimedia.

Conocimiento pensado después de la reunión[edit]

  • Creo que brindar datos de interés público tiene menos restricciones que brindar imágenes o documentos. Por lo que, también podríamos poner atención en organizaciones que cuentan con datos, para posteriormente subir estos datos a Wikidata con herramientas que automatizan este proceso como OpenRefine y QuickStatements. Por ejemplo,
    • Una universidad podría brindar la base de datos de las obras que tiene en su biblioteca y, posteriormente, estos libros y sus metadataos pueden ser subidos a Wikidata.
    • Una organización enfocada en el medio ambiente podría brindar datos sobre derrames de petróleo, contaminación en las ciudades del Perú, montañas del Perú, etc.
  • Durante la reunión, me preguntaron por maneras como WikiAcción Perú podría apoyarme en mis contribuciones de Wikidata. Creo que esta pregunta no la respondí claramente, así que esta es mi respuesta: A largo plazo, me gustaría ver a varios wikimedistas peruanos de todas las partes del Perú usando y contribuyendo a Wikidata con datos de Perú. Por esta razón, me gustaría que podamos pensar en maneras para hacer que más peruanos conozcan las ventajas que les podría traer usar Wikidata y se sientan atraídos a contribuir.
Retrieved from "https://meta.wikimedia.org/w/index.php?title=User/Rdrg109/1/1&oldid=23518599"